forked from weirdNox/org-noter
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathorg-noter.el
1572 lines (1376 loc) · 69 KB
/
org-noter.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;;; org-noter.el --- A synchronized, Org-mode, document annotator -*- lexical-binding: t; -*-
;; Copyright (C) 2017 Gonçalo Santos
;; Author: Gonçalo Santos (aka. weirdNox@GitHub)
;; Homepage: https://github.com/weirdNox/org-noter
;; Keywords: lisp pdf interleave annotate external sync notes documents org-mode
;; Package-Requires: ((emacs "24.4") (cl-lib "0.6") (org "9.0"))
;; Version: 1.0.1
;; This file is not part of GNU Emacs.
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;; The idea is to let you create notes that are kept in sync when you scroll through the
;; document, but that are external to it - the notes themselves live in an Org-mode file. As
;; such, this leverages the power of Org-mode (the notes may have outlines, latex fragments,
;; babel, etc...) while acting like notes that are made /in/ the document.
;; Also, I must thank Sebastian for the original idea and inspiration!
;; Link to the original Interleave package:
;; https://github.com/rudolfochrist/interleave
;;; Code:
(require 'org)
(require 'org-element)
(require 'cl-lib)
(declare-function doc-view-goto-page "doc-view")
(declare-function image-display-size "image-mode")
(declare-function image-get-display-property "image-mode")
(declare-function image-mode-window-get "image-mode")
(declare-function image-scroll-up "image-mode")
(declare-function pdf-view-mode "ext:pdf-view")
(declare-function pdf-view-goto-page "ext:pdf-view")
(declare-function pdf-info-outline "ext:pdf-info")
(declare-function nov-render-document "ext:nov")
(defvar nov-documents-index)
;; --------------------------------------------------------------------------------
;; NOTE(nox): User variables
(defgroup org-noter nil
"A synchronized, external annotator"
:group 'convenience
:version "25.3.1")
(defcustom org-noter-property-doc-file "NOTER_DOCUMENT"
"Name of the property that specifies the document."
:group 'org-noter
:type 'string)
(defcustom org-noter-property-note-location "NOTER_PAGE"
"Name of the property that specifies the location of the current note.
The default value is still NOTER_PAGE for backwards compatibility."
:group 'org-noter
:type 'string)
(defcustom org-noter-default-heading-title "Notes for page $p$"
"The default title for headings created with `org-noter-insert-note'.
$p$ is replaced with the number of the page or chapter you are in
at the moment."
:group 'org-noter
:type 'string)
(defcustom org-noter-notes-window-behavior '(start scroll)
"This setting specifies in what situations the notes window should be created.
When the list contains:
- `start', the window will be created when starting a `org-noter' session.
- `scroll', it will be created when you go to a location with an associated note."
:group 'org-noter
:type '(set (const :tag "Session start" start)
(const :tag "Scrolling" scroll)))
(defcustom org-noter-notes-window-location 'horizontal-split
"Whether the notes should appear in the main frame (horizontal or vertical split) or in a separate frame.
Note that this will only have effect on session startup if `start'
is member of `org-noter-notes-window-behavior' (which see)."
:group 'org-noter
:type '(choice (const :tag "Horizontal" horizontal-split)
(const :tag "Vertical" vertical-split)
(const :tag "Other frame" 'other-frame)))
(defcustom org-noter-auto-save-last-location nil
"When non-nil, save the last visited location automatically; when starting a new session, go to that location."
:group 'org-noter
:type 'boolean)
(defcustom org-noter-hide-other nil
"When non-nil, hide all headings not related to the command
used, like notes from different locations when scrolling."
:group 'org-noter
:type 'boolean)
(defcustom org-noter-always-create-frame t
"When non-nil, org-noter will always create a new frame for the session.
When nil, it will use the selected frame if it does not belong to any other session."
:group 'org-noter
:type 'boolean)
(defcustom org-noter-separate-notes-from-heading nil
"When non-nil, add an empty line between each note's heading and content."
:group 'org-noter
:type 'boolean)
(defcustom org-noter-default-notes-file-names '("Notes.org")
"List of possible names for the default notes file, in increasing order of priority."
:group 'org-noter
:type 'list)
(defface org-noter-no-notes-exist-face
'((t
:foreground "chocolate"
:weight bold))
"Face for modeline note count, when 0."
:group 'org-noter)
(defface org-noter-notes-exist-face
'((t
:foreground "SpringGreen"
:weight bold))
"Face for modeline note count, when not 0."
:group 'org-noter)
;; --------------------------------------------------------------------------------
;; NOTE(nox): Private variables or constants
(cl-defstruct org-noter--session
frame doc-buffer notes-buffer ast modified-tick doc-mode display-name notes-file-path property-text
level num-notes-in-view window-behavior window-location auto-save-last-location hide-other)
(defvar org-noter--sessions nil
"List of `org-noter' sessions.")
(defvar-local org-noter--session nil
"Session associated with the current buffer.")
(defvar org-noter--inhibit-location-change-handler nil
"Prevent location change from updating point in notes.")
(defvar org-noter--start-location-override nil
"Used to open the session from the document in the right page.")
(defvar-local org-noter--nov-timer nil
"Timer for synchronizing notes after scrolling.")
(defconst org-noter--property-behavior "NOTER_NOTES_BEHAVIOR"
"Property for overriding global `org-noter-notes-window-behavior'.")
(defconst org-noter--property-location "NOTER_NOTES_LOCATION"
"Property for overriding global `org-noter-notes-window-location'.")
(defconst org-noter--property-auto-save-last-location "NOTER_AUTO_SAVE_LAST_LOCATION"
"Property for overriding global `org-noter-auto-save-last-location'.")
(defconst org-noter--property-hide-other "NOTER_HIDE_OTHER"
"Property for overriding global `org-noter-hide-other'.")
(defconst org-noter--note-search-no-recurse (delete 'headline (append org-element-all-elements nil))
"List of elements that shouldn't be recursed into when searching for notes.")
;; --------------------------------------------------------------------------------
;; NOTE(nox): Utility functions
(defun org-noter--create-session (ast document-property-value notes-file-path)
(let* ((raw-value-not-empty (> (length (org-element-property :raw-value ast)) 0))
(display-name (if raw-value-not-empty
(org-element-property :raw-value ast)
(file-name-nondirectory document-property-value)))
(frame-name (format "Emacs Org-noter - %s" display-name))
(document (find-file-noselect document-property-value))
(document-path (expand-file-name document-property-value))
(document-major-mode (buffer-local-value 'major-mode document))
(document-buffer-name
(generate-new-buffer-name (concat (unless raw-value-not-empty "Org-noter: ") display-name)))
(document-buffer
(if (eq document-major-mode 'nov-mode)
document
(make-indirect-buffer document document-buffer-name t)))
(notes-buffer
(make-indirect-buffer
(or (buffer-base-buffer) (current-buffer))
(generate-new-buffer-name (concat "Notes of " display-name)) t))
(session
(make-org-noter--session
:display-name display-name
:frame
(if (or org-noter-always-create-frame
(catch 'has-session
(dolist (test-session org-noter--sessions)
(when (eq (org-noter--session-frame test-session) (selected-frame))
(throw 'has-session t)))))
(make-frame `((name . ,frame-name) (fullscreen . maximized)))
(set-frame-parameter nil 'name frame-name)
(selected-frame))
:doc-mode document-major-mode
:property-text document-property-value
:notes-file-path notes-file-path
:doc-buffer document-buffer
:notes-buffer notes-buffer
:level (org-element-property :level ast)
:window-behavior (or (org-noter--notes-window-behavior-property ast) org-noter-notes-window-behavior)
:window-location (or (org-noter--notes-window-location-property ast) org-noter-notes-window-location)
:auto-save-last-location (or (org-noter--auto-save-location-property ast)
org-noter-auto-save-last-location)
:hide-other (or (org-noter--hide-other-property ast) org-noter-hide-other)
:modified-tick -1))
(target-location org-noter--start-location-override))
(add-hook 'delete-frame-functions 'org-noter--handle-delete-frame)
(push session org-noter--sessions)
(with-current-buffer document-buffer
(cond
;; NOTE(nox): PDF Tools
((eq document-major-mode 'pdf-view-mode)
(setq buffer-file-name document-path)
(pdf-view-mode)
(add-hook 'pdf-view-after-change-page-hook 'org-noter--doc-location-change-handler nil t))
;; NOTE(nox): DocView
((eq document-major-mode 'doc-view-mode)
(setq buffer-file-name document-path)
(doc-view-mode)
(advice-add 'doc-view-goto-page :after 'org-noter--location-change-advice))
;; NOTE(nox): Nov.el
((eq document-major-mode 'nov-mode)
(rename-buffer document-buffer-name)
(advice-add 'nov-render-document :after 'org-noter--nov-scroll-handler)
(add-hook 'window-scroll-functions 'org-noter--nov-scroll-handler nil t))
(t (error "This document handler is not supported :/")))
(org-noter-doc-mode 1)
(setq org-noter--session session)
(add-hook 'kill-buffer-hook 'org-noter--handle-kill-buffer nil t))
(with-current-buffer notes-buffer
(org-noter-notes-mode 1)
(setq buffer-file-name notes-file-path
org-noter--session session
fringe-indicator-alist '((truncation . nil)))
(add-hook 'kill-buffer-hook 'org-noter--handle-kill-buffer nil t)
(add-hook 'window-scroll-functions 'org-noter--set-notes-scroll nil t)
(org-noter--set-read-only (org-noter--parse-root))
(unless target-location
(setq target-location (org-noter--location-property (org-noter--get-containing-heading t)))))
(org-noter--setup-windows session)
;; NOTE(nox): This timer is for preventing reflowing too soon.
(run-with-idle-timer
0.05 nil
(lambda ()
(with-current-buffer document-buffer
(let ((org-noter--inhibit-location-change-handler t))
(when target-location (org-noter--doc-goto-location target-location)))
(org-noter--doc-location-change-handler))))))
(defun org-noter--valid-session (session)
(when session
(if (and (frame-live-p (org-noter--session-frame session))
(buffer-live-p (org-noter--session-doc-buffer session))
(buffer-live-p (org-noter--session-notes-buffer session)))
t
(org-noter-kill-session session)
nil)))
(defmacro org-noter--with-valid-session (&rest body)
`(let ((session org-noter--session))
(when (org-noter--valid-session session)
(progn ,@body))))
(defun org-noter--handle-kill-buffer ()
(org-noter--with-valid-session
(let ((buffer (current-buffer))
(notes-buffer (org-noter--session-notes-buffer session))
(doc-buffer (org-noter--session-doc-buffer session)))
;; NOTE(nox): This needs to be checked in order to prevent session killing because of
;; temporary buffers with the same local variables
(when (or (eq buffer notes-buffer)
(eq buffer doc-buffer))
(org-noter-kill-session session)))))
(defun org-noter--handle-delete-frame (frame)
(dolist (session org-noter--sessions)
(when (eq (org-noter--session-frame session) frame)
(org-noter-kill-session session))))
(defun org-noter--parse-root (&optional buffer property-doc-path)
;; TODO(nox): Maybe create IDs in each noter session and use that instead of using
;; the property text that may be repeated... This would simplify some things
(let* ((session (when (org-noter--valid-session org-noter--session) org-noter--session))
(use-args (and (stringp property-doc-path) (buffer-live-p buffer)
(eq (buffer-local-value 'major-mode buffer) 'org-mode)))
(notes-buffer (when use-args buffer))
(wanted-prop (when use-args property-doc-path))
ast)
;; NOTE(nox): Try to use a cached AST
(when (and (not use-args) session)
(setq notes-buffer (org-noter--session-notes-buffer session)
wanted-prop (org-noter--session-property-text session))
(when (= (buffer-chars-modified-tick (org-noter--session-notes-buffer session))
(org-noter--session-modified-tick session))
(setq ast (org-noter--session-ast session))))
(when (and (not ast) (buffer-live-p notes-buffer))
(with-current-buffer notes-buffer
(org-with-wide-buffer
(when
(or
;; NOTE(nox): Start by trying to find a parent heading with the specified
;; property
(catch 'break
(while t
(when (string= wanted-prop
(org-entry-get nil org-noter-property-doc-file))
(org-back-to-heading t)
(throw 'break t))
(unless (org-up-heading-safe) (throw 'break nil))))
;; NOTE(nox): Could not find parent with property, do a global search
(let ((pos (org-find-property org-noter-property-doc-file wanted-prop)))
(when pos (goto-char pos))))
(org-narrow-to-subtree)
(setq ast (car (org-element-contents (org-element-parse-buffer 'greater-element))))
(when session
(setf (org-noter--session-ast session) ast
(org-noter--session-modified-tick session) (buffer-chars-modified-tick)))))))
ast))
(defun org-noter--get-properties-end (ast &optional force-trim)
(when ast
(let* ((contents (org-element-contents ast))
(section (org-element-map contents 'section 'identity nil t 'headline))
(properties (org-element-map section 'property-drawer 'identity nil t))
properties-end)
(if (not properties)
(org-element-property :contents-begin ast)
(setq properties-end (org-element-property :end properties))
(when (or force-trim
(= (org-element-property :end section) properties-end))
(while (not (eq (char-before properties-end) ?:))
(setq properties-end (1- properties-end))))
properties-end))))
(defun org-noter--set-read-only (ast)
(org-with-wide-buffer
(when ast
(let* ((level (org-element-property :level ast))
(begin (org-element-property :begin ast))
(title-begin (+ 1 level begin))
(contents-begin (org-element-property :contents-begin ast))
(properties-end (org-noter--get-properties-end ast t))
(inhibit-read-only t)
(modified (buffer-modified-p)))
(add-text-properties (max 1 (1- begin)) begin '(read-only t))
(add-text-properties begin (1- title-begin) '(read-only t front-sticky t))
(add-text-properties (1- title-begin) title-begin '(read-only t rear-nonsticky t))
(add-text-properties (1- contents-begin) (1- properties-end) '(read-only t))
(add-text-properties (1- properties-end) properties-end
'(read-only t rear-nonsticky t))
(set-buffer-modified-p modified)))))
(defun org-noter--unset-read-only (ast)
(org-with-wide-buffer
(when ast
(let ((begin (org-element-property :begin ast))
(end (org-noter--get-properties-end ast t))
(inhibit-read-only t)
(modified (buffer-modified-p)))
(remove-list-of-text-properties (max 1 (1- begin)) end
'(read-only front-sticky rear-nonsticky))
(set-buffer-modified-p modified)))))
(defun org-noter--set-notes-scroll (window &rest ignored)
(when window
(with-selected-window window
(org-noter--with-valid-session
(let* ((level (org-noter--session-level session))
(goal (* (1- level) 2))
(current-scroll (window-hscroll)))
(when (and (bound-and-true-p org-indent-mode) (< current-scroll goal))
(scroll-right current-scroll)
(scroll-left goal t)))))))
(defun org-noter--insert-heading (level)
(org-insert-heading)
(let* ((initial-level (org-element-property :level (org-element-at-point)))
(changer (if (> level initial-level) 'org-do-demote 'org-do-promote))
(number-of-times (abs (- level initial-level))))
(dotimes (_ number-of-times)
(funcall changer))))
(defun org-noter--narrow-to-root (ast)
(when ast
(save-excursion
(goto-char (org-element-property :begin ast))
(org-show-entry)
(org-narrow-to-subtree)
(org-show-children)
(org-cycle-hide-drawers 'all))))
(defun org-noter--get-doc-window ()
(org-noter--with-valid-session
(or (get-buffer-window (org-noter--session-doc-buffer session)
(org-noter--session-frame session))
(org-noter--setup-windows org-noter--session)
(get-buffer-window (org-noter--session-doc-buffer session)
(org-noter--session-frame session)))))
(defun org-noter--get-notes-window (&optional type)
(org-noter--with-valid-session
(let ((notes-buffer (org-noter--session-notes-buffer session))
(window-location (org-noter--session-window-location session))
(window-behavior (org-noter--session-window-behavior session))
notes-window)
(or (get-buffer-window notes-buffer t)
(when (or (eq type 'force) (memq type window-behavior))
(if (eq window-location 'other-frame)
(let ((restore-frame (selected-frame)))
(switch-to-buffer-other-frame notes-buffer)
(setq notes-window (get-buffer-window notes-buffer t))
(x-focus-frame restore-frame)
(raise-frame (window-frame notes-window)))
(with-selected-window (org-noter--get-doc-window)
(let ((horizontal (eq window-location 'horizontal-split)))
(setq
notes-window
(if (window-combined-p nil horizontal)
;; NOTE(nox): Reuse already existent window
(or (window-next-sibling) (window-prev-sibling))
(if horizontal
(split-window-right)
(split-window-below))))))
(set-window-buffer notes-window notes-buffer))
notes-window)))))
(defun org-noter--setup-windows (session)
"Setup windows when starting session, respecting user configuration."
(when (org-noter--valid-session session)
(with-selected-frame (org-noter--session-frame session)
(delete-other-windows)
(let* ((doc-buffer (org-noter--session-doc-buffer session))
(doc-window (selected-window))
(notes-buffer (org-noter--session-notes-buffer session))
notes-window)
(set-window-buffer doc-window doc-buffer)
(set-window-dedicated-p doc-window t)
(with-current-buffer notes-buffer
(org-noter--narrow-to-root
(org-noter--parse-root notes-buffer (org-noter--session-property-text session)))
(setq notes-window (org-noter--get-notes-window 'start))
(org-noter--set-notes-scroll notes-window))))))
(defmacro org-noter--with-selected-notes-window (error-str &rest body)
(let ((with-error (stringp error-str)))
`(org-noter--with-valid-session
(let ((notes-window (org-noter--get-notes-window)))
(if notes-window
(with-selected-window notes-window
,(unless with-error error-str)
(progn ,@body))
,(when with-error `(user-error "%s" ,error-str)))))))
(defun org-noter--notes-window-behavior-property (ast)
(let ((property (org-element-property (intern (concat ":" org-noter--property-behavior)) ast))
value)
(when (and (stringp property) (> (length property) 0))
(setq value (car (read-from-string property)))
(when (listp value)
value))))
(defun org-noter--notes-window-location-property (ast)
(let ((property (org-element-property (intern (concat ":" org-noter--property-location)) ast))
value)
(when (and (stringp property) (> (length property) 0))
(setq value (intern property))
(when (memq value '(horizontal-split vertical-split other-frame))
value))))
(defun org-noter--auto-save-location-property (ast)
(let ((property (org-element-property (intern (concat ":" org-noter--property-auto-save-last-location)) ast)))
(when (and (stringp property) (> (length property) 0))
(when (intern property)
t))))
(defun org-noter--hide-other-property (ast)
(let ((property (org-element-property (intern (concat ":" org-noter--property-hide-other)) ast)))
(when (and (stringp property) (> (length property) 0))
(when (intern property)
t))))
(defun org-noter--doc-approx-location (&optional precise-location)
(let ((window (if (org-noter--valid-session org-noter--session)
(org-noter--get-doc-window)
(selected-window))))
(assert window)
(with-selected-window window
(cond
((memq major-mode '(doc-view-mode pdf-view-mode))
(cons (image-mode-window-get 'page)
(if (numberp precise-location) precise-location 0)))
((eq major-mode 'nov-mode)
(cons nov-documents-index
(cond
((numberp precise-location) precise-location)
((eq precise-location 'infer) (/ (+ (window-start) (window-end nil t)) 2))
(t 1))))))))
(defun org-noter--location-change-advice (&rest _)
(org-noter--with-valid-session (org-noter--doc-location-change-handler)))
(defun org-noter--nov-scroll-handler (&rest _)
(when org-noter--nov-timer (cancel-timer org-noter--nov-timer))
(unless org-noter--inhibit-location-change-handler
(setq org-noter--nov-timer (run-with-timer 0.25 nil 'org-noter--doc-location-change-handler))))
(defun org-noter--location-property (arg)
(let* ((property
(if (stringp arg) arg
(org-element-property (intern (concat ":" org-noter-property-note-location)) arg)))
value)
(when (and (stringp property) (> (length property) 0))
(setq value (car (read-from-string property)))
(cond ((and (consp value) (integerp (car value)) (numberp (cdr value))) value)
((integerp value) (cons value 0))
(t nil)))))
(defun org-noter--pretty-print-location (location-cons)
(org-noter--with-valid-session
(let ((to-print
(cond
((memq (org-noter--session-doc-mode session) '(doc-view-mode pdf-view-mode))
(if (or (not (cdr location-cons)) (<= (cdr location-cons) 0))
(car location-cons)
location-cons))
((eq (org-noter--session-doc-mode session) 'nov-mode)
(if (or (not (cdr location-cons)) (<= (cdr location-cons) 1))
(car location-cons)
location-cons)))))
(format "%s" to-print))))
(defun org-noter--get-containing-heading (&optional include-root)
"Get smallest containing heading that encloses the point and has location property.
If the point isn't inside any heading with location property, return the outer heading."
(org-noter--with-valid-session
(unless (org-before-first-heading-p)
(org-with-wide-buffer
(org-back-to-heading)
(let ((root-doc-prop (org-noter--session-property-text session))
previous)
(catch 'break
(while t
(let ((prop (org-noter--location-property
(org-entry-get nil org-noter-property-note-location)))
(at-root (string= (org-entry-get nil org-noter-property-doc-file)
root-doc-prop))
(heading (org-element-at-point)))
(when (and prop (or include-root (not at-root)))
(throw 'break heading))
(when (or at-root (not (org-up-heading-safe)))
(throw 'break (if include-root heading previous)))
(setq previous heading)))))))))
(defun org-noter--doc-get-page-slice ()
"Return (slice-top . slice-height)."
(let* ((slice (or (image-mode-window-get 'slice) '(0 0 1 1)))
(slice-top (float (nth 1 slice)))
(slice-height (float (nth 3 slice))))
(when (or (> slice-top 1)
(> slice-height 1))
(let ((height (cdr (image-size (image-mode-window-get 'image) t))))
(setq slice-top (/ slice-top height)
slice-height (/ slice-height height))))
(cons slice-top slice-height)))
(defun org-noter--conv-page-scroll-percentage (scroll)
(let* ((slice (org-noter--doc-get-page-slice))
(display-height (cdr (image-display-size (image-get-display-property))))
(display-percentage (/ scroll display-height))
(percentage (+ (car slice) (* (cdr slice) display-percentage))))
(max 0 (min 1 percentage))))
(defun org-noter--conv-page-percentage-scroll (percentage)
(let* ((slice (org-noter--doc-get-page-slice))
(display-height (cdr (image-display-size (image-get-display-property))))
(display-percentage (min 1 (max 0 (/ (- percentage (car slice)) (cdr slice)))))
(scroll (max 0 (floor (* display-percentage display-height)))))
scroll))
(defun org-noter--ask-precise-location ()
(org-noter--with-valid-session
(let ((window (org-noter--get-doc-window))
event)
(with-selected-window window
(while (not (and (eq 'mouse-1 (car event))
(eq window (posn-window (event-start event)))))
(setq event (read-event "Click where you want the start of the note to be!")))
(cond
((memq (org-noter--session-doc-mode session) '(doc-view-mode pdf-view-mode))
(org-noter--conv-page-scroll-percentage (+ (window-vscroll)
(cdr (posn-col-row (event-start event))))))
((eq (org-noter--session-doc-mode session) 'nov-mode)
(posn-point (event-start event))))))))
(defun org-noter--doc-goto-location (location-cons)
"Go to location specified by LOCATION-CONS."
(org-noter--with-valid-session
(with-selected-window (org-noter--get-doc-window)
(let ((mode (org-noter--session-doc-mode session)))
(cond
((memq mode '(doc-view-mode pdf-view-mode))
(if (eq mode 'pdf-view-mode)
(pdf-view-goto-page (car location-cons))
(doc-view-goto-page (car location-cons)))
(image-scroll-up (- (org-noter--conv-page-percentage-scroll (cdr location-cons))
(window-vscroll))))
((eq mode 'nov-mode)
(setq nov-documents-index (car location-cons))
(nov-render-document)
(goto-char (cdr location-cons))
(recenter))))
;; NOTE(nox): This needs to be here, because it would be issued anyway after
;; everything and would run org-noter--nov-scroll-handler.
(redisplay))))
(defun org-noter--compare-location-cons (comp p1 p2)
"Compare P1 and P2, which are location cons.
When COMP is '<, '<= or '>, it works as expected.
When COMP is '>f, it will return t when P1 is a page greater than
P2 or, when in the same page, if P1 is the _f_irst of the two."
(cond ((not p1) nil)
((not p2) t)
((eq comp '<)
(or (< (car p1) (car p2))
(and (= (car p1) (car p2))
(< (cdr p1) (cdr p2)))))
((eq comp '<=)
(or (< (car p1) (car p2))
(and (= (car p1) (car p2))
(<= (cdr p1) (cdr p2)))))
((eq comp '>)
(or (> (car p1) (car p2))
(and (= (car p1) (car p2))
(> (cdr p1) (cdr p2)))))
((eq comp '>=)
(or (> (car p1) (car p2))
(and (= (car p1) (car p2))
(>= (cdr p1) (cdr p2)))))
((eq comp '>f)
(or (> (car p1) (car p2))
(and (= (car p1) (car p2))
(< (cdr p1) (cdr p2)))))))
(defun org-noter--get-this-note-last-element (note)
(let* ((element-of-different-note
(org-element-map (org-element-contents note) 'headline
(lambda (headline)
(when (org-noter--location-property headline)
headline))
nil t))
(search-in note)
result)
(when element-of-different-note
(setq search-in (org-element-property :parent element-of-different-note)))
(org-element-map (org-element-contents search-in) '(section headline)
(lambda (element)
(if (org-noter--location-property element)
t
(setq result element)
nil))
nil t org-element-all-elements)
(or result
note)))
(defun org-noter--get-this-note-end (note)
"If this notes has no children headings with location properties, then this is the same as `:end'.
If it has, it will be the `:end' of the last element without that location property."
(org-element-property :end (org-noter--get-this-note-last-element note)))
(defun org-noter--focus-notes-region (note-groups)
(when note-groups
(org-noter--with-selected-notes-window
(when (org-noter--session-hide-other session) (org-overview))
(save-excursion
(dolist (group note-groups)
(dolist (note group)
(goto-char (org-element-property :begin note))
(org-show-entry) (org-show-children) (org-show-set-visibility t)
(org-element-map (org-element-contents note) 'headline
(lambda (headline)
(unless (org-noter--location-property headline)
(goto-char (org-element-property :begin headline))
(org-show-entry) (org-show-children)))
nil nil org-element-all-elements))))
(let* ((group (car note-groups)) ;; TODO(nox): This chooses the first group always
(begin (org-element-property :begin (car group)))
(end (org-noter--get-this-note-end (car (last group))))
(window-start (window-start))
(window-end (window-end nil t))
(num-lines (count-lines begin end))
(curr-point (point))
(target (org-noter--get-properties-end (car group)) ))
(if (> num-lines (window-height))
(progn
(goto-char begin)
(recenter 0))
(cond ((< begin window-start)
(goto-char begin)
(recenter 0))
((> end window-end)
(goto-char end)
(recenter -2))))
(if (or (< curr-point begin)
(and (not (eq (point-max) end))
(>= curr-point end)))
(goto-char target)
(goto-char curr-point))
(org-cycle-hide-drawers 'all)))))
(defun org-noter--note-in-view (note-property view)
(cond
((eq (aref view 0) 'paged)
(= (car note-property) (aref view 1)))
((eq (aref view 0) 'nov)
(and (org-noter--compare-location-cons '>= note-property (aref view 1))
(org-noter--compare-location-cons '<= note-property (aref view 2))))))
(defun org-noter--count-notes (notes-in-view)
(org-noter--with-valid-session
(let* ((number-of-notes 0))
(dolist (group notes-in-view) (setq number-of-notes (+ number-of-notes (length group))))
number-of-notes)))
(defun org-noter--get-notes-for-current-view ()
"Returns a list where each element is a list with the notes of
a continuous group of notes."
(org-noter--with-valid-session
(with-selected-window (org-noter--get-doc-window)
(let* ((contents (org-element-contents (org-noter--parse-root)))
(mode (org-noter--session-doc-mode session))
(view
(cond
((memq mode '(doc-view-mode pdf-view-mode))
(vector 'paged (car (org-noter--doc-approx-location))))
((eq mode 'nov-mode)
(vector 'nov (org-noter--doc-approx-location (window-start))
(org-noter--doc-approx-location (window-end nil t))))))
result group)
(org-element-map contents 'headline
(lambda (headline)
(let ((property (org-noter--location-property headline)))
(when property
(if (org-noter--note-in-view property view)
(push headline group)
(when group
(push (nreverse group) result)
(setq group nil))))))
nil nil org-noter--note-search-no-recurse)
(when group (push (nreverse group) result))
(setf (org-noter--session-num-notes-in-view session) (org-noter--count-notes result))
(nreverse result)))))
(defun org-noter--doc-location-change-handler ()
(org-noter--with-valid-session
(let ((notes (org-noter--get-notes-for-current-view)))
(unless org-noter--inhibit-location-change-handler
(force-mode-line-update t)
(when notes
(org-noter--get-notes-window 'scroll)
(org-noter--focus-notes-region notes)))
(when (org-noter--session-auto-save-last-location session) (org-noter-set-start-location nil)))))
(defun org-noter--mode-line-text ()
(org-noter--with-valid-session
(let* ((number-of-notes (or (org-noter--session-num-notes-in-view session) 0)))
(cond ((= number-of-notes 0) (propertize " 0 notes" 'face 'org-noter-no-notes-exist-face))
((= number-of-notes 1) (propertize " 1 note" 'face 'org-noter-notes-exist-face))
(t (propertize (format " %d notes" number-of-notes) 'face 'org-noter-notes-exist-face))))))
;; --------------------------------------------------------------------------------
;; NOTE(nox): User commands
(defun org-noter-set-start-location (arg)
"When opening a session with this document, go to the current location.
With a prefix ARG, remove start location."
(interactive "P")
(org-noter--with-valid-session
(let ((inhibit-read-only t)
(ast (org-noter--parse-root))
(location-cons (org-noter--doc-approx-location 'infer)))
(with-current-buffer (org-noter--session-notes-buffer session)
(org-with-wide-buffer
(goto-char (org-element-property :begin ast))
(if arg
(org-entry-delete nil org-noter-property-note-location)
(org-entry-put nil org-noter-property-note-location
(org-noter--pretty-print-location location-cons))))))))
(defun org-noter-set-auto-save-last-location (arg)
"This toggles saving the last visited location for this document.
With a prefix ARG, delete the current setting and use the default."
(interactive "P")
(org-noter--with-valid-session
(let ((inhibit-read-only t)
(ast (org-noter--parse-root))
(new-setting (if arg
org-noter-auto-save-last-location
(not (org-noter--session-auto-save-last-location session)))))
(setf (org-noter--session-auto-save-last-location session)
new-setting)
(with-current-buffer (org-noter--session-notes-buffer session)
(org-with-wide-buffer
(goto-char (org-element-property :begin ast))
(if arg
(org-entry-delete nil org-noter--property-auto-save-last-location)
(org-entry-put nil org-noter--property-auto-save-last-location (format "%s" new-setting)))
(unless new-setting (org-entry-delete nil org-noter-property-note-location)))))))
(defun org-noter-set-hide-other (arg)
"This toggles hiding other headings for the current session.
- With a prefix \\[universal-argument], set the current setting permanently for this document.
- With a prefix \\[universal-argument] \\[universal-argument], remove the setting and use the default."
(interactive "P")
(org-noter--with-valid-session
(let* ((inhibit-read-only t)
(ast (org-noter--parse-root))
(persistent
(cond ((equal arg '(4)) 'write)
((equal arg '(16)) 'remove)))
(new-setting
(cond ((eq persistent 'write) (org-noter--session-hide-other session))
((eq persistent 'remove) org-noter-hide-other)
('other-cases (not (org-noter--session-hide-other session))))))
(setf (org-noter--session-hide-other session) new-setting)
(when persistent
(with-current-buffer (org-noter--session-notes-buffer session)
(org-with-wide-buffer
(goto-char (org-element-property :begin ast))
(if (eq persistent 'write)
(org-entry-put nil org-noter--property-hide-other (format "%s" new-setting))
(org-entry-delete nil org-noter--property-hide-other))))))))
(defun org-noter-set-notes-window-behavior (arg)
"Set the notes window behaviour for the current session.
With a prefix ARG, it becomes persistent for that document.
See `org-noter-notes-window-behavior' for more information."
(interactive "P")
(org-noter--with-valid-session
(let* ((inhibit-read-only t)
(ast (org-noter--parse-root))
(behavior-possibilities
'(("Default" . nil)
("On start and scroll" . (start scroll))
("On start" . (start))
("On scroll" . (scroll))
("Never" . (never))))
(behavior
(cdr (assoc (completing-read "Behavior: " behavior-possibilities nil t)
behavior-possibilities))))
(setf (org-noter--session-window-behavior session)
(or behavior org-noter-notes-window-behavior))
(when arg
(with-current-buffer (org-noter--session-notes-buffer session)
(org-with-wide-buffer
(goto-char (org-element-property :begin ast))
(if behavior
(org-entry-put nil org-noter--property-behavior
(format "%s" behavior))
(org-entry-delete nil org-noter--property-behavior))))))))
(defun org-noter-set-notes-window-location (arg)
"Set the notes window default location for the current session.
With a prefix ARG, it becomes persistent for that document.
See `org-noter-notes-window-behavior' for more information."
(interactive "P")
(org-noter--with-valid-session
(let* ((inhibit-read-only t)
(ast (org-noter--parse-root))
(location-possibilities
'(("Default" . nil)
("Horizontal split" . horizontal-split)
("Vertical split" . vertical-split)
("Other frame" . other-frame)))
(location
(cdr (assoc (completing-read "Location: " location-possibilities nil t)
location-possibilities)))
(notes-buffer (org-noter--session-notes-buffer session)))
(setf (org-noter--session-window-location session)
(or location org-noter-notes-window-location))
(let (exists)
(dolist (window (get-buffer-window-list notes-buffer nil t))
(setq exists t)
(with-selected-frame (window-frame window)
(if (= (count-windows) 1)
(delete-frame)
(delete-window window))))
(when exists (org-noter--get-notes-window 'force)))
(when arg
(with-current-buffer notes-buffer
(org-with-wide-buffer
(goto-char (org-element-property :begin ast))
(if location
(org-entry-put nil org-noter--property-location
(format "%s" location))
(org-entry-delete nil org-noter--property-location))))))))
(defun org-noter-kill-session (&optional session)
"Kill an `org-noter' session.
When called interactively, if there is no prefix argument and the
buffer has an annotation session, it will kill it; else, it will
show a list of open `org-noter' sessions, asking for which to
kill.
When called from elisp code, you have to pass in the SESSION you
want to kill."
(interactive "P")
(when (and (called-interactively-p 'any) (> (length org-noter--sessions) 0))
;; NOTE(nox): `session' is representing a prefix argument
(if (and org-noter--session (not session))
(setq session org-noter--session)
(setq session nil)
(let (collection default doc-display-name notes-file-name display)
(dolist (session org-noter--sessions)
(setq doc-display-name (org-noter--session-display-name session)
notes-file-name (file-name-nondirectory
(org-noter--session-notes-file-path session))
display (concat doc-display-name " - " notes-file-name))
(when (eq session org-noter--session) (setq default display))
(push (cons display session) collection))
(setq session (cdr (assoc (completing-read "Which session? " collection nil t
nil nil default)
collection))))))
(when (and session (memq session org-noter--sessions))
(setq org-noter--sessions (delq session org-noter--sessions))
(when (eq (length org-noter--sessions) 0)
(remove-hook 'delete-frame-functions 'org-noter--handle-delete-frame)
(advice-remove 'doc-view-goto-page 'org-noter--location-change-advice)
(advice-remove 'nov-render-document 'org-noter--nov-scroll-handler))
(let* ((ast (org-noter--parse-root))
(frame (org-noter--session-frame session))
(notes-buffer (org-noter--session-notes-buffer session))
(base-buffer (buffer-base-buffer notes-buffer))
(notes-modified (buffer-modified-p base-buffer))
(doc-buffer (org-noter--session-doc-buffer session)))
(dolist (window (get-buffer-window-list notes-buffer nil t))
(with-selected-frame (window-frame window)
(if (= (count-windows) 1)
(delete-frame)
(delete-window window))))
(with-current-buffer notes-buffer